*
* Modèles de résistances
*
* Modèle de résistance décrivant son comportement en hautes fréquences
.SUBCKT RES_HIFREQ 1 2	PARAMS: VALUE=1
R	1	3	{VALUE}	; Résistance
L	3	2	7nH	; Inductance série
C	1	2	0.3pF	; Capacité parallèle
.ENDS RES_HIFREQ

* Modèle de résistance incluant son effet en température
.MODEL R_TEMP RES (R=1 TC1=.0001)

* Modèle de potentiomètre
.SUBCKT POT 1 2 3	PARAMS: VALUE=1k SET=.5
R1	1	3	{({VALUE}*(1-{SET}))+.001}
R2	3	2	{({VALUE}*{SET})+.001}
.ENDS

*
* Modèles de capacités
*
* Modèle de capacité décrivant son comportement en hautes fréquences
.SUBCKT CAP_HIFREQ 1 2	PARAMS: VALUE=0.01
R	1	4	0.1	; Résistance parasite
C	4	3	{VALUE}	; Capacité
L	3	2	7nH	; Inductance série
.ENDS CAP_HIFREQ

* Modèle de capacité incluant son effet en température
.MODEL C_TEMP CAP (C=1 TC1=2.38E-3 TC2=-1.48E-4)

*
* Modèles d'inductances
*
* Modèle d'inductance incluant son effet en température
.MODEL L_TEMP IND (R=1 TC1=.0001)

* Modèle d'inductance incluant son effet résistif
.SUBCKT L_RES 1 2	PARAMS: VALUE=0.01
L	1	3	{VALUE}	; Inductance
R	3	2	1	; Résistance série
.ENDS L_RES